1 REM すこしゲームバランスをかえてみた
2 REM 2015/05/20  by akky
3 REM SEをつけてみた
4 REM 2015/05/23  by akky

100 REM---initialize---
110 SCREEN 1,1,1:CONSOLE ,,0,0:CLS
120 CLEAR 50,&HCFFF:GOSUB 740
130 GOSUB 540:SC=0:Y=6:X=15:LASER=3:LEVEL=1:OLDLEVEL=1
140 PLAY "t120l16o6cge-b-o5face-r8e- ","t120l16o4l16gb-cge-cac16r8c16
150 TI=TIME
160 LOCATE1,9:PRINT "LASER:";LA;
170 GOSUB 470

180 REM----main routine----
190 LEVEL=INT((TIME-TI)/1024/10)+1
200 IF OLDLEVEL<LEVEL THEN OL=LE:GOSUB 460:GOTO 220
210 OLDLEVEL=LEVEL
220 S=STICK(0):T=STRIG(0):SC=SC+1
230 X=X+(S=8)*3+(S=7)*3+(S=6)*3-(S=4)*3-(S=3)*3-(S=2)*3
240 X=X-(X<11)*3+(X>20)*3
250 Y=Y+(S=1)*2+(S=2)*2+(S=8)*2-(S=5)*2-(S=4)*2-(S=6)*2
260 Y=Y-(Y<2)*2+(Y>6)*2
270 IF T=1 AND LASER>0 THEN GOSUB490
280 EXEC &HD000:EXEC &HD038
290 LOCATE 4,0:PRINT RIGHT$("    "+STR$(SC)+"0",6);
300 IFSCREEN (1,Y)= 22 THEN 630
310 IFSCREEN(X,15)= 23 THEN 630
320 IFSCREEN (1,Y)=115 THEN LASER=LASER+1:GOSUB420
330 LOCATE1,Y :PRINT "o";
340 LOCATEX,15:PRINT "oo";
350 IF RND(1)<LEVEL/10+.2 THEN LOCATE30,INT(RND(1)*3+1)*2:PRINT"｜";
360 IF RND(1)>.9 THENLOCATE30,INT(RND(1)*3+1)*2:PRINT"s";
370 LOCATE 0,8:PRINT "///////////｜  ｜  ｜  ｜///////////";
380 IF RND(1)<LEVEL/20+.1 THEN GOSUB 410
390 GOTO 190

400 REM----sub routine----
410 LOCATE 8+INT(RND(1)*3+1)*3,8:PRINT "├─┤";:RETURN

420 PLAY "t255l16o7eg+eg+
430 SC=SC+10
440 LOCATE 1,9:PRINT "LASER:";LASER;
450 RETURN

460 PLAY "t255l16o4e-gb-
470 LOCATE 22,9:PRINT "LEVEL:";LEVEL;
480 RETURN

490 PLAY "t255l16o4e-o2e-o3e-o2e-
500 FOR I=2 TO 31:LOCATEI,Y:PRINT "─";:NEXT
510 FOR I=2 TO 31:LOCATEI,Y:PRINT "  ";:NEXT:LASER=LASER-1
520 GOTO 430

530 REM ----がめん-----
540 PRINT "1UP      0       HIGH   "+RIGHT$("     "+STR$(HS)+"0",6)
550 FOR I=0 TO 31:PRINT"─";:NEXT
560 LOCATE 0,7:FOR I=0 TO 31:PRINT"─";:NEXT
570 FOR I=8 TO14:PRINT "///////////          ///////////";:NEXT
580 FOR I=3 TO 5 STEP 2:FOR J=1 TO 31:LOCATE J,I:PRINT "─";:NEXT:NEXT
590 FOR I=8 TO 14:LOCATE 11,I:PRINT "│  │  │  │";:NEXT
600 LOCATE 13,14:PRINT "     ";
610 RETURN

620 REM ----game over----
630 PLAY "t255l16o7e-o6co5a-o4fo3co1e2
640 FORI=0TO15:LOCATE0,15:PRINT:NEXT :EXEC&H1058
650 LOCATE 11,4:PRINT "GAME OVER!"
660 LOCATE  9,7:PRINT "YOUR SCORE:";SC*10
670 LOCATE  9,9:PRINT "YOUR LEVEL:";LE
680 LOCATE 8,12:PRINT "TRY AGAIN? (Y/N)"
690 IF SC>HS THEN HS=SC
700 A$=INKEY$:IF A$="Y" OR A$="y" THEN CLS:GOTO 130
710 IF A$="N" OR A$="n"THEN END
720 GOTO 700

730 REM ----machine word---
740 IF PEEK(&HD000)=&HAF AND PEEK(&HD008)=&HA0 THEN RETURN
750 FOR I=&HD000 TO &HD047:READ A$:POKE I,VAL("&H)+A$):NEXT:RETURN
760 DATA AF,32,60,C2,32,80,C2,32
770 DATA A0,C2,32,C0,C2,32,E0,C2
780 DATA 21,41,C2,11,40,C2,01,AF
790 DATA 00,ED,B0,00,00,00,00,00
800 DATA AF,06,17,32,5F,C2,78,32
810 DATA 7F,C2,AF,32,9F,C2,78,32
820 DATA BF,C2,AF,32,DF,C2,C9,00
830 DATA F5,21,09,10,CD,A9,12,F1
840 DATA C9,00,00,00,00,00,00,00